The Omni Group Forums

The Omni Group Forums (http://forums.omnigroup.com/index.php)
-   AppleScripting Omni Apps (http://forums.omnigroup.com/forumdisplay.php?f=46)
-   -   Tell application WHAT? (a script for the perplexed) (http://forums.omnigroup.com/showthread.php?t=21234)

RobTrew 2011-05-27 03:36 AM

Tell application WHAT? (a script for the perplexed)
 
[IMG]http://farm6.static.flickr.com/5226/5764161995_4bbe46b08f_o.png[/IMG]

It shouldn't be, but the [I]tell application[/I] block is a stumbling block, right at the start of drafting an applescript.

On my system, for example,[INDENT][I]tell application "OmniFocus"[/I][/INDENT]works, but[INDENT]t[I]ell application "OmniOutliner"[/I][/INDENT]fails, and so does[INDENT][I]tell application "OmniGraffle"[/I][/INDENT]
Not only do you have to memorize some slightly arbitrary and inconsistent elaborations like:[INDENT][I]tell application "OmniOutliner Professional"
tell application "OmniGraffle Professional 5"[/I]
[/INDENT]but these references stop even very simple and general scripts from working across variants and versions of the same app (Professional versus vanilla, Ver. N versus Ver. N + 1)

Apple did introduce an improvement around OS X 10.5. Developers, they argued, are unlikely to change an application's 'bundle identifiers' and 'creator codes' across successive versions, whereas they do have a habit of changing its name, and so they introduced the format:[INDENT][I]tell application id "com.omnigroup.OmniGrafflePro"[/I][/INDENT]which looked promising because it didn't contain a version number.

And thus I personally generally switched to forms like:
[INDENT][I]tell application id "com.omnigroup.OmniFocus"[/I][/INDENT]
Which was fine, until I learned that the new AppStore versions have variant bundle names like [I]com.omnigroup.OmniFocus.appstore[/I] and therefore choke on any applescript which starts with a line like the one above ...

So do we sigh and return to things like:[INDENT][I]tell application "OmniGraffle Professional 5"[/I] ?[/INDENT]
This makes sense if code is genuinely version-specific, but is frankly annoying in the numerous cases where the code for OmniOutliner and OmniOutliner Professional, or Omnigraffle vanilla, professional, or version whatever you like, would actually be identical ... (Two versions of OmniOutliner in the same office, professional and plain, and a need for a simple script which would run on both, for example).

This is why I am generally switching to a third application reference variant, which uses [B]tell application id + creator code[/B]. Thus, for example:
[INDENT][I]tell application id "OOut"[/I][/INDENT]for any version of OmniOutliner, and[INDENT][I]tell application id "OGfl"[/I] for any version of OmniGraffle.[/INDENT]
I have even adopted the reflex of [INDENT][I]tell application id "sevs"[/I][/INDENT]in place of [INDENT][I]tell application "System Events"[/I][/INDENT]
All very well, but how do you learn and remember all these four-letter codes ?

Here is a script which will show you the four-letter creator codes (and the longer bundle identifiers) for all the applications currently running on your system. If you want, you can enter a search string, to filter down the list.

It will place a creator code (or bundle identifier) [I]tell application[/I] block, for a selected application, in your clipboard.

(Ver .04 below should be compatible with LaunchBar and Keyboard Maestro. Tap space bar to pass a search string to it directly from LaunchBar).

[CODE]-- Get creator codes and bundle identifiers for tell applications blocks
-- (for applications currently running
-- Ver .05 Compatible with LaunchBar - select script, tap space bar and enter string in Launchbar

property pTitle : "Tell application id ..."

property pDefaultSearch : "omni"

property pCodeCopy : "Copy creator code"
property pBundleCopy : "Copy bundle identifier"
property pNameCopy : "Copy app name"

-- System Events
on run
tell application id "sevs"
activate
set strSearch to text returned of (display dialog "Enter part of application name:

(or leave blank to see all running applications)" default answer pDefaultSearch with title pTitle)
end tell

handle_string(strSearch)
end run

on handle_string(strSearch)
tell application id "sevs"

if (strSearch ≠ "") and (strSearch ≠ "*") then
set {lstCode, lstBundle, lstFile} to {creator type, bundle identifier, file} of (application processes where name contains strSearch and bundle identifier is not missing value)
set strPrompt to "Applications with \"" & strSearch & "\" in their name:"
else
set {lstCode, lstBundle, lstName, lstFile} to {creator type, bundle identifier, name, file} of (application processes where bundle identifier is not missing value)
set strPrompt to "All currently running applications:"
end if
repeat with i from 1 to length of lstCode
set varFile to item i of lstFile
if varFile ≠ missing value then
set strName to (name of item i of lstFile)
else
set strName to item i of lstName
end if

set item i of lstCode to item i of lstCode & "=" & item i of lstBundle & "=" & strName
end repeat

set my text item delimiters to linefeed
set strApps to lstCode as string

set lstApps to paragraphs of (do shell script "echo " & quoted form of strApps & " | sort -t '=' -k 3")
if length of lstApps > 0 then
set lstDefault to {first item of lstApps}
else
activate
display alert "No running apps have names matching " & strSearch
return
end if
activate
set varChoice to choose from list lstApps with prompt strPrompt default items lstDefault with title pTitle

if varChoice is false then return

set my text item delimiters to "="
set {strID, strBundle, strName} to text items 1 thru 3 of first item of varChoice

set {blnCode, blnBundle, blnName} to {true, true, true}

-- CREATOR CODE
if strID ≠ "????" then
set strCode to "tell application id \"" & strID & "\""
else
set blnCode to false
set strCode to strName & " has no creator code ..."
end if

-- BUNDLE IDENTIFIER
if strBundle ≠ "missing value" then
set strBundle to "tell application id \"" & strBundle & "\""
else
set blnBundle to false
set strBundle to strName & " has no bundle identifier"
end if

-- APPLICATION NAME
if strName ends with ".app" then
set strName to text 1 thru -5 of strName
set strAppName to "tell application \"" & strName & "\""
else
set blnName to false
set strAppName to ""
end if


set strChoice to "CREATOR CODE: " & strCode & "

BUNDLE IDENTIFIER: " & strBundle & "

APP NAME: " & strAppName


set lstBtns to {}
if blnName then set end of lstBtns to pNameCopy
if blnBundle then set end of lstBtns to pBundleCopy
if blnCode then set end of lstBtns to pCodeCopy
set lngButtons to length of lstBtns

if lngButtons > 0 then
set strClip to "-- " & strName & return
activate
set strBtn to (button returned of (display dialog strChoice buttons lstBtns default button lngButtons with title strName))
if strBtn = pCodeCopy then
set strClip to strClip & strCode
else if strBtn = pBundleCopy then
set strClip to strClip & strBundle
else
set strClip to strAppName
end if
set the clipboard to strClip & return & return & "end tell"
else
activate
display alert strName & " is not a scriptable process"
end if
set my text item delimiters to space
end tell
end handle_string

[/CODE]

McUsr 2012-06-05 10:34 AM

Great Script
 
Hello, this may come a little bit late, but I have had the same problems with scripting for Quicksilver, which I believe is similar to Launchbar. I have some other fixes.

I have tasted my ways of doing stuff for everything, but a helpwindow on top.

I execute dialogs within the realm of SystemUIServer, because SystemUIserver is faster, since it knows both which screen, and space you are on, I think SystemEvents and Finder are as smart, but not as fast.

[CODE]
tell application "SystemUIServer"
activate
try
set failed to false
display dialog theTime & " will be copied to the Clipboard!" with title procName with icon file clockIcon buttons {"Cancel", "Ok"} default button 2
set the clipboard to theTime
on error
set failed to true
end try
end tell[/CODE]

(There is one detail to note here, that I don't process the errors from the dialog within the scope of SystemUiServer, I postpone that until I'm back into the scope of my script! )

However, since those scripts are in the middle of workflows, I'm pretty picky about specifying default buttons, and cancel buttons, so the script is fully operationable from the keyboard.

When the script is finished, I prefer My screen to be in the same state that I left it, with the same window fully active, without Me having to do anything.
I have this little hack with systemevents pressing down ctrl-F4 for Me, to do that, this will work with every app I think, since it is an OS-function, at least it works with Preview.

[CODE] tell application "System Events" to tell application process frontapp
key down control
key code 118
key up control
end tell[/CODE]
(There is one caveat with this, your screen is exactly as you left it, but! If your first action is to hit return, then you have to hit it twice, I consider this more a feature, than a bug. )

McUsr 2012-06-05 10:59 AM

I actually put in another statement in the last block of code, clearing the keyboard buffer I believe, so now the script runs transparently in the workflow, as if it were never executed when it is done.

Here is the block calling system events to restore it all

[CODE]
tell application "System Events" to tell application process frontapp
key down control
key code 118
key up control
key code 36
end tell[/CODE]

McUsr 2012-06-05 11:25 AM

And this, works under the assumption that volume keys and such are accessed by pressing down the fn -key! :)


All times are GMT -8. The time now is 11:43 PM.

Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2021, vBulletin Solutions, Inc.