I would LOVE LOVE LOVE a global zoom!

Here's a quick and dirty Applescript for setting zoom globally. It's true that the script-accessible zoom is a property of the window, though canvasas obviously retain a zoom level. This script just asks for a new zoom level (default is the current one) and then cycles the canvases through the window to set their zoom level.
[CODE]tell application "OmniGraffle Professional 5"
set currentZoom to the zoom of the front window
set theDialog to display dialog "Zoom all canvases to:" default answer 100 * currentZoom
set theZoom to the text returned of theDialog
set currentCanvas to the canvas of the front window
repeat with theCanv in every canvas in the document of the front window
set the canvas of the front window to theCanv
set the zoom of the front window to theZoom / 100
end repeat
set the canvas of the front window to currentCanvas
end tell[/CODE]

thank you john.gersh!!!!

Thanks John. Do you know if there's a way to set the zoom level to "Fit in Window" (or some way of calculating in the script what the zoom level should be in order to set this?)

Often times after I've been editing a document and left different canvases at different levels, I want to set every page to fit in window so I can look over everything. Can't figure out how to do this.

Here is a rough Zoom to Fit:

[B]NOTE[/B] Now replaced by an improved script in its [URL="http://forums.omnigroup.com/showthread.php?p=105291#post105291"]own thread[/URL].

[CODE]-- ROUGH OMNIGRAFFLE ZOOM TO FIT
-- VER 0.3
-- ADJUST pZoomFactor up or down to suit

property pZoomFactor : 0.8

tell application id "OGfl"
tell front window
set {rX, rY, rX1, rY1} to bounds
set {rWinWidth, rWinHeight} to {rX1 - rX, rY1 - rY}

try
set oFrontCanvas to its canvas
on error
return
end try

repeat with oCanv in canvases of its document
set {lstOrigin, lstSize} to {origin, size} of graphics of oCanv
set lngGraphics to length of lstOrigin
if lngGraphics > 0 then
set {rXMax, rYMax} to {0, 0}
repeat with i from 1 to lngGraphics
set {rX, rY} to item i of lstOrigin
set {rWidth, rHeight} to item i of lstSize
set {rXPosn, rYPosn} to {rX + rWidth, rY + rHeight}
if rXPosn > rXMax then set rXMax to rXPosn
if rYPosn > rYMax then set rYMax to rYPosn
end repeat
set {rXScale, rYScale} to {rWinWidth / rXMax, rWinHeight / rYMax}

set canvas of it to oCanv
if rXScale < rYScale then
set zoom to rXScale * pZoomFactor
else
set zoom to rYScale * pZoomFactor
end if
end if
end repeat
set its canvas to oFrontCanvas
end tell
end tell
[/CODE]

Thanks a bunch Rob. Really appreciate it. This doesn't seem to be working for me at the moment, but I'll hopefully get a chance tomorrow to look more thoroughly to find out what's breaking.

If you've got an empty canvas in your document, the script will crash. Changing the line "set {rXMax, rYMax} to {0, 0}" to "set {rXMax, rYMax} to {1, 1}" is one way to eliminate that issue.

Thank you for spotting that :-)

(I've made an edit above to version 0.2)

It's a very rough sketch and may evolve ...

I also have keyboard assignments to a simple OmniGraffle [B]Zoom OUT[/B] (zooms a bit further out on each keypress)

[CODE]property pTitle : "OG Zoom OUT"
property pFactor : 20

tell application id "OGfl"
tell front window
set dblZoom to zoom - (pFactor / 100)
if dblZoom < 0.05 then set dblZoom to 0.05
set zoom to dblZoom
end tell
end tell
[/CODE]

and a corresponding [B]Zoom IN[/B]

[CODE]property pTitle : "OG Zoom IN"
property pFactor : 20

tell application id "OGfl"
tell front window to set zoom to (zoom + pFactor / 100)
end tell[/CODE]

I've started a [URL="http://forums.omnigroup.com/showthread.php?p=105291#post105291"]new thread[/URL] with a slightly better all canvas zoom to fit,
to make it easier to find.