[fudster]

Looks like they changed the download - now the zip only contains the app.

BTW in Twitterific, I've found that I need to ensure that "Automatically show window when new tweets arrive" is necessary, so that the tweets are marked as read. Else, they are re-processed when the app loads, resulting in dupes. I set it to hide the window after 10 seconds.

Here's my copy of the script (including the necessary mods):

on process_tweet(tweetId, tweetDate, tweetScreenName, tweetUserName, tweetUserUrl, tweetUserImageUrl, tweetText, tweetType)
	
	(*
		This file shows some things you can do with the AppleScript integration in Twitterrific. There are
		two steps for getting this script configured:

		
		Step 1:
		
		Before Twitterrific can run the script, it needs to know where it is located.
		
		To register this AppleScript with Twitterrific, you need to use the Terminal. If the ProcessTweet.scpt file
		is located on the Desktop, you'd use:
		
			defaults write com.iconfactory.Twitterrific processTweetScriptPath "~/Desktop/ProcessTweet.scpt"
			
		You could also use "~/Application Support/Twitterrific/ProcessTweet.scpt" or whatever else makes you happy.
	
		You only need to run this step once.
		
	
		Step 2:
		
		Once the script is registered, you can try out the samples by changing "false" to "true" in the list below:
	*)
	
	set runSpeakingSample to false
	set runUnixShellSample to false
	set runChatSample to false
	set runMailSample to false
	
	
	tell application "OmniFocus" to tell default document
		parse tasks with transport text (tweetText) without as single task
		-- synchronize
	end tell
	
	
	(*	
		Make sure to restart Twitterrific after making any changes above because the script is only loaded at startup.
		

		Uninstalling:
		
		If you decide you don't want to use the script, you can unregister it with the Terminal:
		
			defaults delete com.iconfactory.Twitterrific processTweetScriptPath			

		Have fun!
	*)
	
	if (runSpeakingSample) then
		(*
			Use the Finder to say the user name and text of the tweet that just arrived.
		*)
		tell application "Finder"
			say "Tweet from " & tweetUserName & " saying " & tweetText
		end tell
	end if
	
	if (runUnixShellSample) then
		(*
			Use the Unix shell to log your tweets in a CSV format.
		*)
		do shell script "echo \"'" & tweetId & "', '" & tweetDate & "', '" & tweetScreenName & "', '" & tweetUserName & "', '" & tweetUserUrl & "', '" & tweetUserImageUrl & "', '" & tweetText & "', '" & tweetType & "'\" >> /tmp/tweet.log"
	end if
	
	if (runChatSample) then
		(*
			Use your last tweet to update your iChat status message.
	
			This would be useful for cases where you leave your Mac running and want to update your chat status
			using SMS or the web interface.
		*)
		-- update yourScreenName to be your Twitter screen name
		set yourScreenName to "chockenberry"
		tell application "iChat"
			if (tweetScreenName = yourScreenName) then
				set status message to tweetText
			end if
		end tell
	end if
	
	if (runMailSample) then
		(*
			When a tweet arrives from Darth Vader, compose and send an email to your Mom with the contents of the tweet.
		*)
		if (tweetScreenName = "darthvader") then
			-- update theAccount to be the name of the account in Mail you want to send from
			set theAccount to "Name of your mail account"
			
			-- update this to be whatever you want the message subject to be
			set theSubject to "Tweet from " & tweetUserName
			
			-- update this to be whatever you want the message body to be
			set theContent to "Hi Mom! Thought you might enjoy this: " & tweetText & ". Now don't say I never write! :-)"
			
			-- update theAddress to be whoever gets the message
			set theAddress to "mom@example.com"
			
			tell application "Mail"
				activate
				set newMessage to make new outgoing message with properties {account:theAccount, subject:theSubject, content:theContent}
				tell newMessage
					make new to recipient at end of to recipients with properties {address:theAddress}
					set visible to true
				end tell
				-- uncomment the following line if you want the message to be sent automatically
				--send newMessage
			end tell
		end if
	end if
	
end process_tweet