View Single Post
Another small script: Inbox notifier. I often forget that I got something in my inbox by a sync with iSync from my mobile. This script will check for old tasks (creation date > 24 hours ago) and then displays a Growl message:

Code:
on notify(theDescription)
	tell application "GrowlHelperApp"
		set the allNotificationsList to {"Inbox not empty"}
		set the enabledNotificationsList to {"Inbox not empty"}
		
		register as application ¬
			"OmniFocus Inbox Notifier" all notifications allNotificationsList ¬
			default notifications enabledNotificationsList ¬
			icon of application "OmniFocus"
		
		notify with name ¬
			"Inbox not empty" title ¬
			"Inbox not empty" description ¬
			theDescription application name "OmniFocus Inbox Notifier" with sticky
	end tell
end notify

tell front document of application "OmniFocus"
	set oldTasks to inbox tasks whose its creation date < (current date) - 3600 * 24
	set inboxCount to count of oldTasks
	if inboxCount > 0 then
		if inboxCount > 1 then
			my notify((inboxCount as string) & " tasks are waiting.")
		else
			my notify((inboxCount as string) & " task is waiting.")
		end if
	end if
end tell
I let it run once a day via an recurring iCal event.

Schimmi