The Omni Group Forums - View Single Post - Variable color for bullets and disclosure triangles

RobTrew

I like to toggle between light and dark screen modes for editing in OmniOutliner. I find that the dark mode is the least distracting, and the best for quickly gathering and shaping first thoughts.

OO3's bullets, disclosure triangles and in-line editing cursors are, however, fixed at black, and disappear on a black screen background.

Even on a white screen, I would personally prefer gray bullets and triangles (i.e. slightly muted, one cognitive plane behind the text itself).

If non-black bullets and triangles would help your work too, do send a request (probably for oo4) through Help > Send Feedback in the OO menu.

FWIW the screen toggling script which I am using looks like this:

Code:

-- Cycle between a print mode, a light screen mode, and a dark screen mode
-- (The screen modes use larger characters)
property pVer : "0.2"

property pScreenSize : 18
property pPrintSize : 12

property pLightBackColor : {253, 246, 233}
property pLightForeColor : {102, 102, 118}

property pDarkBackColor : {0, 0, 0}
property pDarkForeColor : {203, 75, 22}

property pPrint : 1
property pLightScreen : 2
property pDarkScreen : 3
property plngState : 1

property pPrintFont : "Helvetica"
property pScreenFont : "Monaco"

property pBack : "text-background-color"
property pFore : "font-fill"
property pFont : "font-family"
property pSize : "font-size"

on run
	set plngState to plngState + 1
	if plngState > 3 then set plngState to 1
	ToggleSize(plngState)
end run

on ToggleSize(plngState)
	tell application id "OOut"
		if (count of documents) < 1 then return
		if plngState = pPrint then
			set lstStyle to {pBack, pFore, {pFont, pPrintFont}, {pSize, pPrintSize}}
		else
			set lstStyle to {{pFont, pScreenFont}, {pSize, pScreenSize}}
			
			if plngState = pLightScreen then
				set lstStyle to lstStyle & {{pBack, my FullDepth(pLightBackColor)}, {pFore, my FullDepth(pLightForeColor)}}
			else
				set lstStyle to lstStyle & {{pBack, my FullDepth(pDarkBackColor)}, {pFore, my FullDepth(pDarkForeColor)}}
			end if
		end if
		
		tell style of front document
			repeat with oProp in lstStyle
				if class of oProp is list then
					tell attribute (item 1 of oProp) to set value to (item 2 of oProp)
				else
					tell attribute oProp to set value to default value
				end if
			end repeat
		end tell
	end tell
end ToggleSize

on FullDepth({lngR, lngG, lngB})
	{lngR * 256, lngG * 256, lngB * 256}
end FullDepth