The Omni Group
These forums are now read-only. Please visit our new forums to participate in discussion. A new account will be required to post in the new forums. For more info on the switch, see this post. Thank you!

Go Back   The Omni Group Forums > OmniFocus > Applying OmniFocus
FAQ Members List Calendar Search Today's Posts Mark Forums Read

 
Returning to no folders Thread Tools Search this Thread Display Modes
Hi all,

So after having implemented a long folder hierarchy representing my areas of responsibility, etc., returning to OF I find that I'm longing for the simplicity of a true GTD implementation (see e.g. David Allen Co whitepaper on Entourage): so I'm going to dispense with my folders (right now I'm keeping Work/Personal, but I plan to do away with that soon as well).
I really enjoyed having a "reminder" of my areas of responsibilities and of long-term projects that are more abstract than concrete (e.g.: "X years later, be happy having made decision Y now"). I've found that TaskPaper works really well for me for this kind of stuff, so I'm going to try to have it running across the 3 platforms (Mac, iPhone, iPad) along with OF so I can get both foci.
In the meantime, I'd really love to hear from those of you who have not been using folders for any tips/tricks/advice and/or problems arising with large numbers of projects.

Thanks!
 
Quote:
Originally Posted by hypotyposis View Post
after having implemented a long folder hierarchy representing my areas of responsibility ... I'm going to dispense with my folders (right now I'm keeping Work/Personal, but I plan to do away with that soon as well).
There is a cost to folders (visual clutter, and the need to drill down), but, as is suggested by your hesitation over dropping the Work / Personal folders, there is a value too.

I find that you can get the best of both worlds by keeping folders but being able to click a button which hides the folder hierarchy completely, and just shows a flat list of all your projects.

This is the script I use, and it can be fine-tuned ...

Code:
-- Hide folder hierarchy and display a flat list of all projects

tell application "OmniFocus"
	set oDoc to default document
	set lstProjects to my ProjectList(oDoc)
	set focus of front document window of oDoc to lstProjects
end tell

on ProjectList(oParent)
	using terms from application "OmniFocus"
		tell oParent
			-- ADJUST THE WHERE QUERIES TO MATCH 
			--THE TYPE OF PROJECTS YOU WANT TO LIST
			set lstProjects to projects where (status is active) or (status is on hold)
			set lstFolders to folders where hidden is false
		end tell
		repeat with oFolder in lstFolders
			set lstProjects to lstProjects & my ProjectList(oFolder)
		end repeat
		return lstProjects
	end using terms from
end ProjectList
 
Thanks for the script!

I just re-implemented folders, or actually a more AofF folder structure. I was hesitant since I'd tried something similar before but I decided the key for me is to set up some more good perspectives. But knowing that I can 'flatten' things with a couple clicks will be nice too.
 
Quote:
Originally Posted by malisa View Post
I just re-implemented folders, or actually a more AofF folder structure ... but knowing that I can 'flatten' things with a couple clicks will be nice too.
This version of the script behaves as a toggle - the first click gives a flat view, a second click returns to folder view.

Code:
-- Toggle between a flat and a folder-indented sidebar
-- (An experiment in conditional compilation, as latest Sneaky Peaks 
-- offer quicker (and more rationally ordered) 
-- flattening of the project list)

property pstrNewScript : "
script
on GetProjects(oDoc)
	using terms from application \"OmniFocus\"
		return flattened projects of oDoc
	end using terms from
end GetProjects
end script
"

property pstrOldScript : "
script
on GetProjects(oParent)
	using terms from application \"OmniFocus\"
		tell oParent
			-- ADJUST THE WHERE QUERIES TO MATCH THE PURPOSE
			set lstProjects to projects
			set lstFolders to folders
		end tell
		repeat with oFolder in lstFolders
			set lstProjects to lstProjects & my GetProjects(oFolder)
		end repeat
		return lstProjects
	end using terms from
end GetProjects
end script
"

tell application id "com.omnigroup.OmniFocus"
	set oDoc to default document
	set oWin to front document window of oDoc
	
	if my IsNarrowed(focus of oWin) then
		set focus of oWin to {}
	else
		if build number ≥ "77.57.0.134152" then
			set oScript to run script pstrNewScript
		else
			set oScript to run script pstrOldScript
		end if
		set lstProjects to GetProjects(oDoc) of oScript
		set focus of oWin to lstProjects
	end if
end tell

-- Detect whether the sidebar has a narrowed focus
on IsNarrowed(oFocus)
	repeat with oObj in oFocus
		return true
	end repeat
	return false
end IsNarrowed

Last edited by RobTrew; 2010-06-22 at 10:23 PM..
 
RobTrew - thanks very much for the script! It is still helpful as I have folders for checklists, etc. But, I am pleased to report, I have done away completely with folders otherwise! Yes, that includes the Personal/Professional distinction!

Now we'll just have to see how long this lasts for...

I'm finding, though, that using a good set of perspectives linked to in my review projects seems to get me by adequately so far.

bmushrush – I should also note that, in my opinion, the RSD scripts for Read/Review stuff are one of the best way to deal with having lots of PDFs (or any other file format, really) to read on the computer, if by chance that's something you have to deal with...

Cheers!
 
Quote:
Originally Posted by RobTrew View Post
This version of the script behaves as a toggle - the first click gives a flat view, a second click returns to folder view.
Nice! That's some impressive scripting, Rob. I love the embedding of the script definitions in properties to use the new flatten option when it's available.
__________________
Cheers,

Curt
 
Quote:
Originally Posted by curt.clifton View Post
I love the embedding of the script definitions in properties to use the new flatten option when it's available.
Thank you, Curt ! The playing around with Run Script goes back to our discussion about scope for run-time editing of Where/Whose clauses. (It does turn out to be possible, though I have not quite decided whether that is the root of an odd interaction between the OO3 toolbar script-launcher and my row-filtering scripts)
 
Thanks RobTrew for the scripts and comments... I think if I return to folders, this will definitely be the way to go.
To address something you said, though, I'm not actually hesitant to break down the personal/work hierarchy, I just needed some spare time (getting to it now) to coalesce Single Action lists together and decide whether I actually want to keep any more SA lists than the original "Miscellaneous" (which I spent so much time hating in the beginning...). For me, breaking down the distinction between work and personal items actually was a great jump not just in productivity but in overall "happiness", which occurred after my first read of GTD. I think I got a bit too involved with the "tinkering with the system" thing by playing with folders and establishing (not-so-)arbitrary delimitations—not saying no-one can benefit from folders, etc.; just relating my personal experience.
I'd be very interested to hear from you and from Malisa, if you wouldn't mind sharing, what your folder hierarchies are, and what your perspectives/workflow look like.

Thanks!
 
Awhile back, I had a hierarchy of folders relating to abstract concepts like "Personal Development", etc. I believe this was from me trying to implement too much of Getting Things Done into Omnifocus. It was too much.

I left Omnifocus for awhile, and since I've been back, I use Folders strictly for Areas of Focus. I have three: Personal, Work, and one more for an organization I volunteer for. That's it. (If I didn't spend a considerable amount of time with the organization, I would have just lumped that in with Personal). There's no drilling down any further. Plus, I can use the Focus feature with Perspectives and my Areas of Focus.

This works great for me. Anything more (or less) is too chaotic.
 
Rob, thank you so much! I love this script as I have always struggled with folders vs. flat list. This is awesome!

Why doesn't Omni adopt some of the awesome scripts Rob, Cliff, et. al develop? These jewels are often buried in the forums.

Steve
 
 


Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
Returning User down8ve OmniWeb Feature Requests 0 2011-10-15 02:20 PM
Continuous/returning tasks Esparza OmniPlan General 0 2011-01-11 05:44 AM
Returning to default perspectives? ghoetker OmniFocus 1 for Mac 1 2010-11-28 07:50 PM
Script for returning from focus to overview RobTrew OmniFocus Extras 0 2010-08-21 02:36 AM
no folders visible if no folders selected henri OmniFocus 1 for Mac 6 2008-11-19 09:03 AM


All times are GMT -8. The time now is 01:43 PM.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2014, vBulletin Solutions, Inc.