The Omni Group
These forums are now read-only. Please visit our new forums to participate in discussion. A new account will be required to post in the new forums. For more info on the switch, see this post. Thank you!

Go Back   The Omni Group Forums > OmniFocus > OmniFocus for iPhone
FAQ Members List Calendar Search Today's Posts Mark Forums Read

 
Please make a way to tell the difference between projects and task Forecast view! Thread Tools Search this Thread Display Modes
Quote:
Originally Posted by whpalmer4 View Post
Easy fix for that — don't! If there's a number there, there's work to be done, just do it. The only time you need to audit the badge count is if it still says there is work to be done, and you can't find it.
Yep for sure during a work flow. However, my review flow is different than my work flow, and I am just being principled about it for the sake of the review process.

Alternatively, one might ask for a preference setting to just show a colored dot as a badge without containing a count of "actionable items". It could even be a "perspective dependent" setting. That is one change I could swallow right away, because, as you suggest, I hardly pay attention to the exact number in the count box during a work flow process (especially since I know it is ambiguous anyway). I sometimes do want to process with repect to that number during my review processes though.

Quote:
Originally Posted by whpalmer4 View Post
.. but it seems like a more complete solution would be to either not show project/action group headers at all in task lists (already an option in context mode, and perhaps forecast view ought to respect the setting as well) or remove the ability to check them off without first completing the actions.
Yep. I agree here. Forecast mode is where the trouble is. I would imagine holy terror will arise should OG remove the existing "auto-complete" feature on Action Groups. That leaves modifying the how Action Groups (auto-complete or otherwise) are handled/displayed in Forecast mode as a more viable choice.

Quote:
Originally Posted by whpalmer4 View Post
Your original text was "checking a Project completed checks all its actions" ....
Oh! I meant checking a GROUP completed / uncompleted. I missed that note even after you pointed it out directly. My apologies. I'll go bang my head against a brick wall a few times to make amends ... :\

In this regard, as Brian has noted already, the UNDO option gets me back on the Mac (and I did not even think about it ... duh!!!)

Quote:
Originally Posted by whpalmer4 View Post
The iPad app handles the issue of differentiating actions and projects/action groups by styling the projects and action groups differently ...
An equivalent distinction would be very helpful to have on the iPod version for sure.

Thanks!

--
JJW
 
Quote:
Originally Posted by Brian View Post
...Since an existing feature of the OS does a good job of handling this situation, we feel there are other things we should work on adding to our apps. Everything else is possible, however. :-)
Thanks. Good information to "remember" (about undo), and good news also to hear (about feature requests).

--
JJW
 
Quote:
Originally Posted by DrJJWMac View Post
Alternatively, one might ask for a preference setting to just show a colored dot as a badge without containing a count of "actionable items".
Now this I can help you with today :-)
http://forums.omnigroup.com/showpost...31&postcount=7

Unfortunately, you have to restart OmniFocus when you change this, and the strings are a bit tedious to type, but you could write a shell script or two to do the dirty work for you to switch between a "Review" view (with numbered badges) and a "Work" view (with just the colored dots).
Quote:
Yep. I agree here. Forecast mode is where the trouble is. I would imagine holy terror will arise should OG remove the existing "auto-complete" feature on Action Groups. That leaves modifying the how Action Groups (auto-complete or otherwise) are handled/displayed in Forecast mode as a more viable choice.
I'm assuming you mean the feature where checking the action group completes all the contained actions, not the feature where the action group is automatically checked off when you complete the last contained action. I don't know that I would get very upset about the former going away, given the ability to select a group of actions and mark them completed in a single operation I previously mentioned. If Omni is getting lots of support calls from people who are getting bitten, I could understand putting a safety guard on the sharp blade, so to speak, even if it is a little less convenient for the power user. It certainly wouldn't be the first time, and I'm sure it wouldn't be the last.

Quote:
Oh! I meant checking a GROUP completed / uncompleted. I missed that note even after you pointed it out directly. My apologies. I'll go bang my head against a brick wall a few times to make amends ... :\
No sweat, I forgot that projects and action groups behave differently in this particular regard!
 
Quote:
Originally Posted by whpalmer4 View Post
Now this I can help you with today :-)
http://forums.omnigroup.com/showpost...31&postcount=7

Unfortunately, you have to restart OmniFocus when you change this, and the strings are a bit tedious to type, but you could write a shell script or two to do the dirty work for you to switch between a "Review" view (with numbered badges) and a "Work" view (with just the colored dots).
Thanks. I remember glancing over this post. I'll consider writing a script hanging on a FastScripts call to toggle the state.

--
JJW
 
Perhaps I can save you the trouble:

Code:
-- button labels for dialog
property pWork : "Work"
property pReview : "Review"
property pReset : "Reset"
-- strings for shell commands to set OmniFocus parameters
property pDefaultsWriteCommand : "defaults write"
property pDefaultsDeleteCommand : "defaults delete"
property pOmniFocusDomain : "com.omnigroup.OmniFocus "
-- badge names
property pInboxBadge : "InboxBadge"
property pAvailableBadge : "AvailableBadge"
property pDueSoonBadge : "DueSoonBadge"
property pOverdueBadge : "OverdueBadge"
-- badge options
property pCount : "count"
property pDot : "dot"
property pNone : "none"

-- Set up preferred badge settings here.  Badge options are {pCount, pDot, pNone}.
property pReviewAvailableBadge : pCount
property pReviewDueSoonBadge : pCount
property pReviewOverdueBadge : pCount
property pReviewInboxBadge : pCount

property pWorkAvailableBadge : pDot
property pWorkDueSoonBadge : pDot
property pWorkOverdueBadge : pDot
property pWorkInboxBadge : pDot

on run
	set recReply to display dialog "Set badges for Work or Review?" buttons {pWork, pReview, pReset}
	set btnChosen to button returned of recReply
	
	tell application "System Events"
		if (exists process "OmniFocus") then
			tell application "OmniFocus" to quit
		end if
		repeat until not (exists process "OmniFocus")
			delay 0.2 -- give it some time to do so 
		end repeat
	end tell
	
	if btnChosen is pWork then
		SetDefault(pAvailableBadge, pWorkAvailableBadge)
		SetDefault(pDueSoonBadge, pWorkDueSoonBadge)
		SetDefault(pOverdueBadge, pWorkOverdueBadge)
		SetDefault(pInboxBadge, pWorkInboxBadge)
	else if btnChosen is pReview then
		SetDefault(pAvailableBadge, pReviewAvailableBadge)
		SetDefault(pDueSoonBadge, pReviewDueSoonBadge)
		SetDefault(pOverdueBadge, pReviewOverdueBadge)
		SetDefault(pInboxBadge, pReviewInboxBadge)
	else if btnChosen is pReset then
		ResetDefault(pAvailableBadge)
		ResetDefault(pDueSoonBadge)
		ResetDefault(pOverdueBadge)
		ResetDefault(pInboxBadge)
	end if
	
	activate application "OmniFocus" -- restart OmniFocus with new settings
end run

on SetDefault(sBadge, pSetting)
	do shell script pDefaultsWriteCommand & space & pOmniFocusDomain & space & sBadge & space & pSetting
end SetDefault

on ResetDefault(sBadge)
	try
		do shell script pDefaultsDeleteCommand & spcae & pOmniFocusDomain & space & sBadge
	on error
		-- probably didn't have a setting to delete
	end try
end ResetDefault
This script offers 3 choices (Work, Review, Reset). Work and Review set the badges as configured near the top of the script (default being colored dot for work, number for review), Reset returns them to the factory settings. OmniFocus then quits and reopens with the new settings.
 
 


Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
Viewing Projects in Forecast view TylerJames OmniFocus for iPad 1 2012-03-13 08:35 AM
Forecast view? abisot OmniFocus for iPhone 1 2011-04-23 11:30 AM
View and Sort Task List across selection of multiple Projects os4 OmniFocus 1 for Mac 2 2010-11-17 09:59 AM
Difference between Parallel projects and Single Action Lists Leila OmniFocus 1 for Mac 6 2009-07-28 03:44 AM
Difference between Groups, Projects and Folders netvisionary OmniFocus 1 for Mac 28 2008-08-30 12:15 PM


All times are GMT -8. The time now is 04:01 AM.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2024, vBulletin Solutions, Inc.