The Omni Group
These forums are now read-only. Please visit our new forums to participate in discussion. A new account will be required to post in the new forums. For more info on the switch, see this post. Thank you!

Go Back   The Omni Group Forums > OmniFocus > OmniFocus 1 for Mac
FAQ Members List Calendar Search Today's Posts Mark Forums Read

 
Processing items to dropped folder Thread Tools Search this Thread Display Modes
So I've got my Someday/Maybe as a dropped folder containing multiple projects and single action lists (which are active, but inherit the dropped status). However, this doesn't seem to let me assign any of the Someday/Maybe projects to inbox items when typing it in the action's project column.
Any ideas?

EDIT: And while I'm at it, I don't find a way to filter the view so that it hides completed projects but still shows projects in a dropped folder?

Thanks!

Last edited by hypotyposis; 2010-05-26 at 09:15 PM..
 
OmniFocus presumes that something which has been dropped is something you really truly aren't going to work on. Based on that presumption, it doesn't include the contents in the completion cell, so you don't have to wade through a bunch of options you've said you don't want to work on.

The ability to set a folder to "On Hold" instead of dropping it should be coming in version 2; that sounds like it'll do what you're looking for. In current releases, though, you're going to have to un-drop the folders to get the items they contain to show up in the completion cells. Sorry.
 
Thanks Brian—this actually answers my question. I think it's a problem that had been raised quite some time ago already regarding handling of someday/maybe in OF... I guess I was expecting it to have been resolved!
 
Quote:
Originally Posted by Brian View Post
The ability to set a folder to "On Hold" instead of dropping it should be coming in version 2; that sounds like it'll do what you're looking for.
In the meanwhile, the status of all projects in the selected folder (and any sub-folders which it may have) can be set to On Hold (or back to Active), with the applescript below.

(the status of any Completed or Dropped projects is left unchanged)

Code:
-- Ver 0.8
-- Sets status of contents and descendants of the selected folder(s) and project(s) to ON HOLD or ACTIVE
-- (depending on user response to a prompt)
-- The status of any COMPLETED and DROPPED projects is left unchanged
-- Any DROPPED subfolders are also left unchanged

property pActive : "Active"
property pOnHold : "On Hold"

tell application id "com.omnigroup.OmniFocus"
	tell front window
		set oPanel to sidebar
		if (count of selected trees of oPanel) < 1 then
			set oPanel to content
			set lstFolders to {}
		else
			set lstFolders to value of (selected trees of oPanel where 
				(class of value is folder) and (hidden of value is false))
		end if
		set refProjects to a reference to value of (selected trees of oPanel where 
			(class of value is project) and ((status of value is active) or (status of value is on hold)))
	end tell
	
	set varChoice to choose from list {pActive, pOnHold} with prompt "Set selection & descendants to:"
	if varChoice is not false then
		if first item of varChoice is pActive then
			set eNewStatus to active
		else
			set eNewStatus to on hold
		end if
		
		set status of refProjects to eNewStatus
		repeat with oFolder in lstFolders
			my SetFolderStatus(oFolder, eNewStatus)
		end repeat
	end if
end tell

on SetFolderStatus(oFolder, eNewStatus)
	using terms from application "OmniFocus"
		set refProjects to a reference to (projects of oFolder where ((status is active) or (status is on hold)))
		set status of refProjects to eNewStatus
		
		set lstFolders to folders of oFolder where hidden is false
		repeat with oSubFolder in lstFolders
			my SetFolderStatus(oSubFolder, eNewStatus)
		end repeat
	end using terms from
end SetFolderStatus
--

Last edited by RobTrew; 2010-05-29 at 09:51 PM.. Reason: Logic moved to where statements (faster)
 
That script works very well-thanks Rob!
 
A version which simply toggles folder contents between On Hold and Active (without prompting for a choice) is on another thread.

--

Last edited by RobTrew; 2010-05-28 at 06:05 AM..
 
Quote:
Originally Posted by RobTrew View Post
In the meanwhile, the status of all projects in the selected folder (and any sub-folders which it may have) can be set to On Hold (or back to Active), with the applescript below.

(the status of any Completed or Dropped projects is left unchanged)
--
Ahhhh... This is exactly what I needed! Thank you so much, Rob! The v. 2.0 ability (which I understand would default projects sent to a "On Hold" folder to on-hold themselves [like projects in a dropped folder currently inherit the dropped status]) is indeed exactly what I'm looking for, as "Someday/Maybe" doesn't work as a context for me (in the way generally described by the Omni staff, but not in the DA whitepaper...). I know the perils of this approach and wish I could deal with "emptying my head" to separate inboxes (e.g. like Curt does), but I just have to have that happen in one system: hence I'm going to try again for "everything in OF", which means having a solid Someday/Maybe implementation (i.e. including for unlikely projects).
 
 


Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
Archiving / Definition of 'Dropped Items'? chmars OmniFocus 1 for Mac 2 2011-06-28 10:15 AM
Filtering by Overdue Items breaks Sequential processing SpiralOcean OmniFocus 1 for Mac 11 2009-02-18 01:40 AM
Processing Waiting For Items SpiralOcean OmniFocus 1 for Mac 14 2007-10-14 02:23 AM
What happens to a task dropped on a project folder? smew OmniFocus 1 for Mac 2 2007-05-31 06:09 AM


All times are GMT -8. The time now is 02:51 AM.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2019, vBulletin Solutions, Inc.