-- For OF 1.8+ only
-- 1. Toggles between folder hierarchy and  a flat list of all projects
-- 2. Setting the view to the user's top-level default  (here Project view, Remaining Projects, Remaining Tasks)
--		(Sorting and Grouping settings are left unchanged)


tell application id "com.omnigroup.OmniFocus"
	tell default document
		set oWin to front document window
		
		if selected view mode identifier of oWin is not "project" then ¬
			set selected view mode identifier of oWin to "project"
		
		if my IsNarrowed(focus of oWin) then
			set focus of oWin to {}
		else
			set lstProjects to flattened projects
			set focus of oWin to lstProjects
		end if
		
		my SetFilters(oWin, {"remaining", "-", "-", "incomplete", "", ""}, false)
		select tree 2 of sidebar of oWin
	end tell
end tell

on IsNarrowed(oFocus)
	repeat with oItem in oFocus
		return true
	end repeat
	return false
end IsNarrowed

on SetFilters(oWin, {strSmartGroup, strGrouping, strSorting, strState, strFlagged, strDurn}, blnContext)
	if blnContext then
		set strClass to "-contexts"
	else
		set strClass to "-projects"
	end if
	tell application id "com.omnigroup.omnifocus"
		tell oWin
			if strSmartGroup is not "" then
				if strSmartGroup is not "-" then if selected smart group identifier of sidebar is not strSmartGroup then ¬
					set selected smart group identifier of sidebar to strSmartGroup & strClass
			else
				set selected smart group identifier of sidebar to "all" & strClass
			end if
			tell content
				if strGrouping is not "" then
					if strGrouping is not "-" then if selected grouping identifier is not strGrouping then ¬
						set selected grouping identifier to strGrouping
				else
					set selected grouping identifier to "none"
				end if
				if strSorting is not "" then
					if strSorting is not "-" then if selected sorting identifier is not strSorting then ¬
						set selected sorting identifier to strSorting
				else
					if blnContext then
						set selected sorting identifier to "context"
					else
						set selected sorting identifier to "none"
					end if
				end if
				if strState is not "" then
					if strState is not "-" then if selected task state filter identifier is not strState then ¬
						set selected task state filter identifier to strState
				else
					set selected task state filter identifier to "all"
				end if
				if strFlagged is not "" then
					if strFlagged is not "-" then if selected task flagged filter identifier is not strFlagged then ¬
						set selected task flagged filter identifier to strFlagged
				else
					set selected task flagged filter identifier to "all"
				end if
				if strDurn is not "" then
					if strDurn is not "-" then if selected task duration filter identifier is not strDurn then ¬
						set selected task duration filter identifier to strDurn
				else
					set selected task duration filter identifier to "any"
				end if
			end tell
		end tell
	end tell
end SetFilters