The Omni Group
These forums are now read-only. Please visit our new forums to participate in discussion. A new account will be required to post in the new forums. For more info on the switch, see this post. Thank you!

Go Back   The Omni Group Forums > OmniFocus > OmniFocus 1 for Mac
FAQ Members List Calendar Search Today's Posts Mark Forums Read

 
Recurring in Dutch language Thread Tools Search this Thread Display Modes
I am having this most annoying phenomenon: Whenever I try to set a recurring action to a (multiple) of a month ("maand" in Dutch) OF resets my entry to Minutes ("minuut" in Dutch).

Eg. Recurring every "3 maand" resets to every "3 minutes"

I have tried to use almost every permutation of "maand" including all prural variations but to no avail.

I have no clue if I am doing something wrong. I get around by entering the recurring action in a number of weeks, but I do have to do my expenses once every month and I have no way to enter this.

Is this a bug in the Dutch localization of OF?
 
Quote:
Originally Posted by dg005978 View Post
Is this a bug in the Dutch localization of OF?
Something does seem to have gone wrong in the management of the localization process - there have been reports of broken repeat dialogs in other languages.

http://forums.omnigroup.com/showthread.php?p=91743

The first port of call should be Help > Send Feedback ... in the OmniFocus menu.

You may still be able, in the meanwhile, to set repeat intervals through applescript (see below).

--

Last edited by RobTrew; 2011-04-11 at 10:58 AM..
 
Selecting a task and running a script like this, for example, should allow you to set Due Date intervals.

(An unusual blind patch in the Applescript library puts Start Date intervals beyond the reach of script, alas ... combining this with the breaking of repetition dialogs by localisations, repetition does look a bit neglected and in need of repair at the moment ...)

Code:
property pTitle : "Set repetition interval"
property pstrDefault : "unit:week, fixed:true, steps:1"
property pNoRepn : "No repetition"

tell application id "OFOC"
	tell front document window of front document
		set lstTasks to value of (selected trees of content where class of its value is task or class of its value is inbox task)
		if (count of lstTasks) < 1 then return
		tell first item of lstTasks
			set strName to name
			tell repetition
				set strLegend to "unit: day | week | month | year

fixed:true = repeat every N units
fixed:false = repeat N units after completion

"
				if it is not missing value then
					tell it as record
						set {blnFixed, lngSteps, eUnit} to {fixed, steps, unit}
					end tell
					set strUnit to eUnit as string
					
					
					set strLegend to "unit: day | week | month | year

fixed:true = repeat every N units
fixed:false = repeat N units after completion

"
					set strLegend to strLegend & my Translate(blnFixed, lngSteps, strUnit)
					
					set strCode to (("unit:" & strUnit & ", fixed:" & blnFixed as string) & ", steps:" & lngSteps as string)
					
					
				else
					set strCode to pstrDefault
					set strLegend to strLegend & "
Not repeating.
					
Enter a repetition string:"
				end if
				
				
				set blnParsed to false
				repeat while not blnParsed
					set varResponse to (display dialog strLegend default answer strCode buttons {"Cancel", pNoRepn, "OK"} 
						cancel button "Cancel" default button "OK" with title pTitle)
					if button returned of varResponse = pNoRepn then
						set strCode to "missing value"
					else
						set strCode to text returned of varResponse
						set strCode to do shell script "echo " & quoted form of strCode & " | perl -pe 's/(day|week|month|year)s/\\1/'"
					end if
					
					try
						set recRep to run script "tell application id \"OFOC\"
				{" & strCode & "}
				end tell"
						set blnParsed to true
					on error strMsg
						set strLegend to strMsg & "
						
						
The interval should be of the form:

" & pstrDefault
					end try
				end repeat
			end tell
			try
				set repetition to recRep
				tell repetition as record
					set {blnFixed, lngSteps, eUnit} to {fixed, steps, unit}
				end tell
				set strUnit to eUnit as string
				display alert my Translate(blnFixed, lngSteps, strUnit) message "(" & strName & ")"
			on error
				set repetition to missing value
				display alert "Not repeating" message "(" & strName & ")"
			end try
		end tell
	end tell
end tell


on Translate(blnFixed, lngSteps, strUnit)
	set strPlural to "s"
	if lngSteps = 1 then set strPlural to ""
	set strPeriod to (lngSteps as string) & space & strUnit & strPlural
	
	if blnFixed then
		"Repeating every " & strPeriod
	else
		"Repeating " & strPeriod & " after completion"
	end if
end Translate

Last edited by RobTrew; 2011-04-11 at 01:25 PM.. Reason: updated code to add a "no repetition" button
 
Sorry for the trouble here - I handled an email from a customer reporting the same issue in Spanish. I'll make sure the rest of the team knows about both bugs.

(Rob, if you email the support ninjas about the trouble you ran into with your script, we can write that up for you, as well.)
 
Thanks Brian.

The gap in the Applescript library (repeating start dates can not be scripted) has been reported before.

The broken repetition dialog has also been reported before for Chinese (simplified), as well as Spanish (and now Dutch).

It's not the writing up that's missing :-)

A fairly basic piece of specified functionality that is simply not working for users of at least three languages, and which is also out of reach to the usual fall-back of scripting. Perhaps one of those cases where the majoritarian hegemony system of prioritisation (by Anglo-Saxon voting) is not entirely appropriate ? ;-)


--

Last edited by RobTrew; 2011-04-11 at 03:20 PM..
 
Actually, it looks like the issue is getting some attention for the 1.9 release. Note to self: check the bug database. Curse Mondays. :-)
 
多谢 !dankjewel, 等等 ...
 
The repetition sections of the Action and Project inspectors do indeed seem to be working in the Chinese and Dutch localisations of 1.9 ... (I haven't checked Spanish).

Good !

However, the repetition interval record in the OmniFocus Applescript library still lacks a boolean flag to read or write the state of the start again vs due again repetition option.

(Start again in one month versus Due again in one month is an option offered in the inspector, and encoded in the SQlite cache as ~2(s)m versus ~2m, but Applescript can't tell the difference or set the option :-(

Does the bug database suggest a prognosis for this ?

--

Last edited by RobTrew; 2011-04-12 at 10:30 PM..
 
 


Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
Options for recurring list, not recurring task jason.verly Applying OmniFocus 2 2009-07-13 04:10 PM
Dealing with recurring tasks/recurring projects smiggles Applying OmniFocus 4 2009-01-14 10:42 AM


All times are GMT -8. The time now is 08:52 AM.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2018, vBulletin Solutions, Inc.