The Omni Group
These forums are now read-only. Please visit our new forums to participate in discussion. A new account will be required to post in the new forums. For more info on the switch, see this post. Thank you!

Go Back   The Omni Group Forums > OmniFocus > OmniFocus Extras
FAQ Members List Calendar Search Today's Posts Mark Forums Read

 
AppleScript that adds Waiting For emails from Mail.app (delegated tasks) to OmniFocus Thread Tools Search this Thread Display Modes
Hey Guys - I was finally able to get this script working in Mountain Lion. See my script below. I had made some other minor changes to the very original script, so please double check that this does what you want it to do.

The main changes that I made to make it work in Mountain Lion were the following:

- changed 'on_perform_mail_Action(theData) to on 'perform mail action with messages theData' with corresponding 'end' statement
- removed 'tell application "Mail"' and corresponding 'end tell'
- removed line 'set theMessages to |SelectedMessages| of theData --Extract the messages from the rule'
- changed repeat code from 'repeat with theMessage in theMessages' to 'repeat with theMessage in theData'

With the changes above, the script works perfectly for me in Mountain Lion.





Code:
(*
	Waiting For Mails to OmniFocus Script
	by simplicityisbliss.com, Sven Fechner
	MailTags project and due date compatibility added by Scott Morrison, Indev Software
	
	Based on an Outbox Rule (Mail Act-On) in Mail.app this script adds specific messages
	to the OmniFocus Inbox with the waiting for context
	
	MailTags is required to automatically set the project and the due date.

	Mail Act-On (www.indev.ca) is required to define the Outbox Rule to only
	create tasks for those outgoing emails that are to be tracked in OmniFocus
	
	A sample Outbox rule may be
	if MailTags Tickle Date is After 0 days today  
	Run Apple Script: [ThisAppleScript]
	
				
	The script uses Growl from the App Store for feedback notification if it is installed and running
	
*)


--!! EDIT THE PROPERTIES BELOW TO MEET YOUR NEEDS !!--

-- Do you want the actualy mail body to be added to the notes section of the OmniFocus task?
-- Set to 'true' is or 'false' if no
property mailBody : true

-- Text between mail recipient (the person you are waiting for to come back) and the email subject
property MidFix : "to follow up re:"

-- Name of your Waiting For context in OmniFocus
property myWFContext : "Waiting For"

-- Default start time
property timeStart : "5:00:00 AM"

-- Default due time
property timeDue : "6:00:00 PM"

-- Default start to due date interval, in days
property dateInterval : "3"

-- !! STOP EDITING HERE IF NOT FAMILAR WITH APPLESCRIPT !! --

--Configuration for Growl messages 
property GrowlRun : true
property scriptName : "Waiting For Mails to OmniFocus"
property notifySuccess : "Success Notification"
property notifyFail : "Failed Notification"
property titleSuccess : "Waiting For Mail added"
property titleFail : "Waiting For Mail to OmniFocus FAILED"
property txtSuccess : " added to OmniFocus successfully"
property txtFail : " to OmniFocus to add successfully"
property txtIcon : "OmniFocus"

using terms from application "Mail"
	
	on perform mail action with messages theData
		--Check if Growl is running
		tell application "System Events" to set GrowlRun to (count of (every process whose name is "GrowlHelperApp")) > 0
		
		--Setup Growl
		if GrowlRun then tell application "AppleScript Editor" to «event register» given «class appl»:scriptName, «class anot»:{notifySuccess, notifyFail}, «class dnot»:{notifySuccess, notifyFail}, «class iapp»:txtIcon
		
		--Get going
		--tell application "Mail"
		--set theMessages to |SelectedMessages| of theData --Extract the messages from the rule
		repeat with theMessage in theData
			--repeat with theMessage in theMessages
			set theSubject to subject of theMessage
			set theRecipient to name of to recipient of theMessage
			set theMessageID to urlencode(the message id of theMessage) of me
			set theStartDate to ""
			set theDueDate to ""
			
			try
				using terms from application "MailTagsHelper"
					set theStartDate to (due date of theMessage) as date
					set theStartDate to my setStartDate(theStartDate)
					set theDueDate to theStartDate + dateInterval * days
					set theDueDate to my setDueDate(theDueDate)
				end using terms from
			on error theError
				
			end try
			
			-- Check if there is one or more recipients
			try
				if (count of theRecipient) > 1 then
					set theRecipientName to (item 1 of theRecipient & (ASCII character 202) & "and" & (ASCII character 202) & ((count of theRecipient) - 1) as string) & (ASCII character 202) & "more"
				else
					set theRecipientName to item 1 of theRecipient
				end if
				
				set theTaskTitle to theRecipientName & (ASCII character 202) & MidFix & (ASCII character 202) & theSubject
				set messageURL to "Created from message://%3C" & (theMessageID) & "%3E"
				set theBody to messageURL
				if mailBody then set theBody to theBody & return & return & the content of theMessage
				
				-- Add waiting for context task to OmniFocus
				tell application "OmniFocus"
					tell default document
						set theContext to context myWFContext
						
						if theStartDate is not "" then
							set theTask to make new inbox task with properties {name:theTaskTitle, note:theBody, context:theContext, start date:theStartDate, due date:theDueDate}
						else
							set theTask to make new inbox task with properties {name:theTaskTitle, note:theBody, context:theContext}
							
						end if
						if myProject is not null then
							set theProject to project myProject
							move theTask to end of tasks of theProject
							
						end if
					end tell
				end tell
				
			on error theError
				do shell script "logger -t outboxrule 'Error : " & theError & "' "
			end try
			
			my GrowlSuccess("Mail: " & theSubject)
		end repeat
		--end tell
		
	end perform mail action with messages
	
	on GrowlSuccess(theMessage)
		if GrowlRun then tell application "AppleScript Editor" to «event notifygr» given «class name»:notifySuccess, «class titl»:titleSuccess, «class desc»:theMessage & txtSuccess, «class appl»:scriptName
	end GrowlSuccess
	
	on urlencode(theText)
		set theTextEnc to ""
		repeat with eachChar in characters of theText
			set useChar to eachChar
			set eachCharNum to ASCII number of eachChar
			if eachCharNum = 32 then
				set useChar to "+"
			else if (eachCharNum ≠ 42) and (eachCharNum ≠ 95) and (eachCharNum < 45 or eachCharNum > 46) and (eachCharNum < 48 or eachCharNum > 57) and (eachCharNum < 65 or eachCharNum > 90) and (eachCharNum < 97 or eachCharNum > 122) then
				set firstDig to round (eachCharNum / 16) rounding down
				set secondDig to eachCharNum mod 16
				if firstDig > 9 then
					set aNum to firstDig + 55
					set firstDig to ASCII character aNum
				end if
				if secondDig > 9 then
					set aNum to secondDig + 55
					set secondDig to ASCII character aNum
				end if
				set numHex to ("%" & (firstDig as string) & (secondDig as string)) as string
				set useChar to numHex
			end if
			set theTextEnc to theTextEnc & useChar as string
		end repeat
		return theTextEnc
	end urlencode
	
	on setStartDate(theStartDate)
		set theDate to (date string of theStartDate)
		set newDate to the (date (theDate & " " & timeStart))
		return newDate
	end setStartDate
	
	on setDueDate(theDueDate)
		set theDate to (date string of theDueDate)
		set newDate to the (date (theDate & " " & timeDue))
		return newDate
	end setDueDate
	
end using terms from
 
Thanks a lot! You saved my life :D
 
Hi SpinalTap...

I copied your script and tried it...no luck.

Is this the exact script that you're using with ML?

Thanks...Brett

Edited August 29, 2012 6:16 PM
Thanks...after line by line review of the script and tweaking of the Growl sections it works fine.

Cheers

Last edited by bpwhistler; 2012-08-29 at 04:16 PM..
 
I get a Growl confirmation that the task has been added, but nothing shows up in my inbox.

Looking at the console i get this error


06-09-12 13:54:33,663 outboxrule[40046]: Error : OmniFocus got an error: Can’t get context "Waiting for ..." of default document.

This is the script i use

(*
Waiting For Mails to OmniFocus Script
by simplicityisbliss.com, Sven Fechner
MailTags project and due date compatibility added by Scott Morrison, Indev Software

Based on an Outbox Rule (Mail Act-On) in Mail.app this script adds specific messages
to the OmniFocus Inbox with the waiting for context

MailTags is required to automatically set the project and the due date.

Mail Act-On (www.indev.ca) is required to define the Outbox Rule to only
create tasks for those outgoing emails that are to be tracked in OmniFocus

A sample Outbox rule may be
if MailTags Tickle Date is After 0 days today
Run Apple Script: [ThisAppleScript]


The script uses Growl from the App Store for feedback notification if it is installed and running

*)


--!! EDIT THE PROPERTIES BELOW TO MEET YOUR NEEDS !!--

-- Do you want the actualy mail body to be added to the notes section of the OmniFocus task?
-- Set to 'true' is or 'false' if no
property mailBody : true

-- Text between mail recipient (the person you are waiting for to come back) and the email subject
property MidFix : "to follow up re:"

-- Name of your Waiting For context in OmniFocus
property myWFContext : "Waiting for ..."

-- Default start time
property timeStart : "06:00:00"

-- Default due time
property timeDue : "14:00:00"

-- Default start to due date interval, in days
property dateInterval : "3"

-- !! STOP EDITING HERE IF NOT FAMILAR WITH APPLESCRIPT !! --

--Configuration for Growl messages
property GrowlRun : true
property scriptName : "Waiting For Mails to OmniFocus"
property notifySuccess : "Success Notification"
property notifyFail : "Failed Notification"
property titleSuccess : "Waiting For Mail added"
property titleFail : "Waiting For Mail to OmniFocus FAILED"
property txtSuccess : " added to OmniFocus successfully"
property txtFail : " to OmniFocus to add successfully"
property txtIcon : "OmniFocus"

using terms from application "Mail"

on perform mail action with messages theData
--Check if Growl is running
tell application "System Events" to set GrowlRun to (count of (every process whose name is "Growl")) > 0

--Setup Growl
if GrowlRun then tell application "Growl" to register as application scriptName all notifications {notifySuccess, notifyFail} default notifications {notifySuccess, notifyFail} icon of application txtIcon

--Get going
-- tell application "Mail"
-- set theMessages to |SelectedMessages| of theData --Extract the messages from the rule
-- repeat with theMessage in theMessages
repeat with theMessage in theData
set theSubject to subject of theMessage
set theRecipient to name of to recipient of theMessage
set theMessageID to urlencode(the message id of theMessage) of me
set theStartDate to ""
set theDueDate to ""

try
using terms from application "MailTagsHelper"
set theStartDate to (due date of theMessage) as date
set theStartDate to my setStartDate(theStartDate)
set theDueDate to theStartDate + dateInterval * days
set theDueDate to my setDueDate(theDueDate)
end using terms from
on error theError

end try

-- Check if there is one or more recipients
try
if (count of theRecipient) > 1 then
set theRecipientName to (item 1 of theRecipient & (ASCII character 202) & "and" & (ASCII character 202) & ((count of theRecipient) - 1) as string) & (ASCII character 202) & "more"
else
set theRecipientName to item 1 of theRecipient
end if

set theTaskTitle to theRecipientName & (ASCII character 202) & MidFix & (ASCII character 202) & theSubject
set messageURL to "Created from message://%3C" & (theMessageID) & "%3E"
set theBody to messageURL
if mailBody then set theBody to theBody & return & return & the content of theMessage

-- Add waiting for context task to OmniFocus
tell application "OmniFocus"
tell the default document
set theContext to context "Waiting for ..."


if theStartDate is not "" then
set theTask to make new inbox task with properties {name:theTaskTitle, note:theBody, context:theContext, start date:theStartDate, due date:theDueDate}
else
set theTask to make new inbox task with properties {name:theTaskTitle, note:theBody, context:theContext}

end if
if myproject is not null then
set theProject to project myproject
move theTask to end of tasks of theProject

end if
end tell
end tell

on error theError
do shell script "logger -t outboxrule 'Error : " & theError & "' "
end try


my GrowlSuccess("Mail: " & theSubject)
end repeat
-- end tell

-- end perform_mail_action

end perform mail action with messages

on GrowlSuccess(theMessage)
if GrowlRun then tell application "Growl" to notify with name notifySuccess title titleSuccess description theMessage & txtSuccess application name scriptName
end GrowlSuccess

on urlencode(theText)
set theTextEnc to ""
repeat with eachChar in characters of theText
set useChar to eachChar
set eachCharNum to ASCII number of eachChar
if eachCharNum = 32 then
set useChar to "+"
else if (eachCharNum ≠ 42) and (eachCharNum ≠ 95) and (eachCharNum < 45 or eachCharNum > 46) and (eachCharNum < 48 or eachCharNum > 57) and (eachCharNum < 65 or eachCharNum > 90) and (eachCharNum < 97 or eachCharNum > 122) then
set firstDig to round (eachCharNum / 16) rounding down
set secondDig to eachCharNum mod 16
if firstDig > 9 then
set aNum to firstDig + 55
set firstDig to ASCII character aNum
end if
if secondDig > 9 then
set aNum to secondDig + 55
set secondDig to ASCII character aNum
end if
set numHex to ("%" & (firstDig as string) & (secondDig as string)) as string
set useChar to numHex
end if
set theTextEnc to theTextEnc & useChar as string
end repeat
return theTextEnc
end urlencode

on setStartDate(theStartDate)
set theDate to (date string of theStartDate)
set newDate to the (date (theDate & " " & timeStart))
return newDate
end setStartDate

on setDueDate(theDueDate)
set theDate to (date string of theDueDate)
set newDate to the (date (theDate & " " & timeDue))
return newDate
end setDueDate

end using terms from
 
Obvious first thing to check would be that you have a top-level context with the same name that the script is expecting. There's a property definition near the top that seems to supply the name, but in fact the script doesn't use it, doesn't handle the case where the context doesn't exist in any way, and doesn't handle a context which is nested inside another. Brings to mind the infamous quote:
"If builders built buildings the way programmers write programs, then the first woodpecker that came along would destroy civilization."
 
Quote:
Originally Posted by whpalmer4 View Post
Obvious first thing to check would be that you have a top-level context with the same name that the script is expecting. There's a property definition near the top that seems to supply the name, but in fact the script doesn't use it, doesn't handle the case where the context doesn't exist in any way, and doesn't handle a context which is nested inside another.
The original script used this property, but the script posted by @bugvi is missing the code that references the property. A quick glance of the script shows this:

Code:
set theContext to context "Waiting for ..."
which bypasses the property that is intended to be set in the myWFContext statement. Who knows what else is now broken in this script?
 
Changed it to myWFContext and made a new top-level context and it works again. Thanks for the help.
 
Hi bugvi...

I had this script working in ML, and then it just stopped. I don't think I changed anything. I'm not getting anything into my OF inbox or any Growl notifications.

I tried using the script you posted exactly (with the fixed myWFContext) with no success.

Code:
(*
Waiting For Mails to OmniFocus Script
by simplicityisbliss.com, Sven Fechner
MailTags project and due date compatibility added by Scott Morrison, Indev Software

Based on an Outbox Rule (Mail Act-On) in Mail.app this script adds specific messages
to the OmniFocus Inbox with the waiting for context

MailTags is required to automatically set the project and the due date.

Mail Act-On (www.indev.ca) is required to define the Outbox Rule to only
create tasks for those outgoing emails that are to be tracked in OmniFocus

A sample Outbox rule may be
if MailTags Tickle Date is After 0 days today 
Run Apple Script: [ThisAppleScript]


The script uses Growl from the App Store for feedback notification if it is installed and running

*)


--!! EDIT THE PROPERTIES BELOW TO MEET YOUR NEEDS !!--

-- Do you want the actualy mail body to be added to the notes section of the OmniFocus task?
-- Set to 'true' is or 'false' if no
property mailBody : true

-- Text between mail recipient (the person you are waiting for to come back) and the email subject
property MidFix : "to follow up re:"

-- Name of your Waiting For context in OmniFocus
property myWFContext : "Waiting for ..."

-- Default start time
property timeStart : "06:00:00"

-- Default due time
property timeDue : "14:00:00"

-- Default start to due date interval, in days
property dateInterval : "3"

-- !! STOP EDITING HERE IF NOT FAMILAR WITH APPLESCRIPT !! --

--Configuration for Growl messages 
property GrowlRun : true
property scriptName : "Waiting For Mails to OmniFocus"
property notifySuccess : "Success Notification"
property notifyFail : "Failed Notification"
property titleSuccess : "Waiting For Mail added"
property titleFail : "Waiting For Mail to OmniFocus FAILED"
property txtSuccess : " added to OmniFocus successfully"
property txtFail : " to OmniFocus to add successfully"
property txtIcon : "OmniFocus"

using terms from application "Mail"
	
	on perform mail action with messages theData
		--Check if Growl is running
		tell application "System Events" to set GrowlRun to (count of (every process whose name is "Growl")) > 0
		
		--Setup Growl
		if GrowlRun then tell application "Growl" to register as application scriptName all notifications {notifySuccess, notifyFail} default notifications {notifySuccess, notifyFail} icon of application txtIcon
		
		--Get going
		-- tell application "Mail"
		-- set theMessages to |SelectedMessages| of theData --Extract the messages from the rule
		-- repeat with theMessage in theMessages
		repeat with theMessage in theData
			set theSubject to subject of theMessage
			set theRecipient to name of to recipient of theMessage
			set theMessageID to urlencode(the message id of theMessage) of me
			set theStartDate to ""
			set theDueDate to ""
			
			try
				using terms from application "MailTagsHelper"
					set theStartDate to (due date of theMessage) as date
					set theStartDate to my setStartDate(theStartDate)
					set theDueDate to theStartDate + dateInterval * days
					set theDueDate to my setDueDate(theDueDate)
				end using terms from
			on error theError
				
			end try
			
			-- Check if there is one or more recipients
			try
				if (count of theRecipient) > 1 then
					set theRecipientName to (item 1 of theRecipient & (ASCII character 202) & "and" & (ASCII character 202) & ((count of theRecipient) - 1) as string) & (ASCII character 202) & "more"
				else
					set theRecipientName to item 1 of theRecipient
				end if
				
				set theTaskTitle to theRecipientName & (ASCII character 202) & MidFix & (ASCII character 202) & theSubject
				set messageURL to "Created from message://%3C" & (theMessageID) & "%3E"
				set theBody to messageURL
				if mailBody then set theBody to theBody & return & return & the content of theMessage
				
				-- Add waiting for context task to OmniFocus
				tell application "OmniFocus"
					tell the default document
						set theContext to context "myWFContext"
						
						
						if theStartDate is not "" then
							set theTask to make new inbox task with properties {name:theTaskTitle, note:theBody, context:theContext, start date:theStartDate, due date:theDueDate}
						else
							set theTask to make new inbox task with properties {name:theTaskTitle, note:theBody, context:theContext}
							
						end if
						if myProject is not null then
							set theProject to project myProject
							move theTask to end of tasks of theProject
							
						end if
					end tell
				end tell
				
			on error theError
				do shell script "logger -t outboxrule 'Error : " & theError & "' "
			end try
			
			
			my GrowlSuccess("Mail: " & theSubject)
		end repeat
		--	end tell
		
		-- end perform_mail_action
		
	end perform mail action with messages
	
	on GrowlSuccess(theMessage)
		if GrowlRun then tell application "Growl" to notify with name notifySuccess title titleSuccess description theMessage & txtSuccess application name scriptName
	end GrowlSuccess
	
	on urlencode(theText)
		set theTextEnc to ""
		repeat with eachChar in characters of theText
			set useChar to eachChar
			set eachCharNum to ASCII number of eachChar
			if eachCharNum = 32 then
				set useChar to "+"
			else if (eachCharNum ≠ 42) and (eachCharNum ≠ 95) and (eachCharNum < 45 or eachCharNum > 46) and (eachCharNum < 48 or eachCharNum > 57) and (eachCharNum < 65 or eachCharNum > 90) and (eachCharNum < 97 or eachCharNum > 122) then
				set firstDig to round (eachCharNum / 16) rounding down
				set secondDig to eachCharNum mod 16
				if firstDig > 9 then
					set aNum to firstDig + 55
					set firstDig to ASCII character aNum
				end if
				if secondDig > 9 then
					set aNum to secondDig + 55
					set secondDig to ASCII character aNum
				end if
				set numHex to ("%" & (firstDig as string) & (secondDig as string)) as string
				set useChar to numHex
			end if
			set theTextEnc to theTextEnc & useChar as string
		end repeat
		return theTextEnc
	end urlencode
	
	on setStartDate(theStartDate)
		set theDate to (date string of theStartDate)
		set newDate to the (date (theDate & " " & timeStart))
		return newDate
	end setStartDate
	
	on setDueDate(theDueDate)
		set theDate to (date string of theDueDate)
		set newDate to the (date (theDate & " " & timeDue))
		return newDate
	end setDueDate
	
end using terms from
Is this the script you have working?

Thanks,

Brett
 
Does anybody have this script working in 10.8.2? If so, could you post your script?

Thanks...Brett
 
I'm still using the one I posted here back in February-works fine for me on 10.8.2.
 
 


Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
How to deal with delegated or "waiting for" actions bisimpson Applying OmniFocus 20 2013-02-27 06:52 AM
Delegated tasks? mattw OmniFocus 1 for Mac 35 2011-10-07 02:10 PM
Sync with Omnifocus on Mac adds completed tasks.. ohla313 OmniFocus for iPhone 7 2011-06-13 08:50 AM
Script to add delegated tasks from entourage to "Waiting" context in OmniFocus tarun101 OmniFocus Extras 1 2010-05-21 08:09 AM
Adding Tasks Via Send To OmniFocus Mail Rule, Mailtags, & Mail Act-On reuben OmniFocus 1 for Mac 0 2007-11-18 06:07 PM


All times are GMT -8. The time now is 02:02 AM.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2019, vBulletin Solutions, Inc.