[Mbas]

Hi. I have a tree of connected objects in my canvas. I want to highlight a path between the leaf and the root every time I click on the leaf object. All my leaves and the root are normal shapes that are connected through lines. One way I have thought about it is writing an applescript that highlights the lines leading to the root. But I am new to writing scripts and need help there. Any help/suggestions is much appreciated

The Edit > Select > Ancestors menu option is a built-in way of doing something like this, but if you need to do it through Applescript for any reason (to select only ancestral links, or only ancestral nodes, rather than both, for example) a simple sketch might look something like this, which extends the selection up through the ancestral path.

Editing the value of the properties pblnNodes and pblnLinks at the start of the script (setting each to true or false) will enable you to determine whether it is the ancestral nodes which are highlighted, or the ancestral links, or both.

-- ver 0.03

property pblnNodes : true
property pblnLinks : false

tell application id "OGfl"
	if (count of documents) < 1 then return
	tell front window
		set lstPaths to {}
		repeat with oShape in (selection as list)
			if (class of oShape) is shape then
				set lstPaths to lstPaths & my GetPath(oShape, pblnNodes, pblnLinks)
			end if
		end repeat
		set selection to lstPaths
	end tell
end tell

on GetPath(oShape, blnNodes, blnLinks)
	tell application id "OGfl"
		set lstIncoming to incoming lines of oShape
		if lstIncoming ≠ {} then
			set oLink to first item of lstIncoming
			set lstPath to my GetPath(source of oLink, blnNodes, blnLinks)
			if blnLinks then set lstPath to lstPath & {oLink}
			if blnNodes then set lstPath to lstPath & {oShape}
		else
			if blnNodes then
				set lstPath to {oShape}
			else
				set lstPath to {}
			end if
		end if
		return lstPath
	end tell
end GetPath

--

You should be able to get this to work in response to a Browse Tool click if you specify script actions for particular leaf nodes.

Inspectors > Action > Runs a Script

and enter or paste something like the following:

set selection of front window to GetPath(self, true, true)

on GetPath(oShape, blnNodes, blnLinks)
	tell application id "OGfl"
		set lstIncoming to incoming lines of oShape
		if lstIncoming ≠ {} then
			set oLink to first item of lstIncoming
			set lstPath to my GetPath(source of oLink, blnNodes, blnLinks)
			if blnLinks then set lstPath to lstPath & {oLink}
			if blnNodes then set lstPath to lstPath & {oShape}
		else
			if blnNodes then
				set lstPath to {oShape}
			else
				set lstPath to {}
			end if
		end if
		return lstPath
	end tell
end GetPath

This works in editing view, but I notice that it generates an error in presentation view. A quick note to the Ninjas thru Help > Send Feedback … may enable you to learn whether there is a syntax which enables script-driven selection in presentation mode.

--

Mmm …

Doesn't look like it. It seems that none of this is possible in Presentation Mode – 'selection' is only defined for edit mode

Finally, to attach the script action to all shapes in the canvas which you are editing, so that any one of them will highlight the ancestral path in response to a click from the Browse tool, you could run something like this:

property pScript : "
set selection of front window to getpath(self, true, true)
on getpath(oShape, blnNodes, blnLinks)
	tell application id \"OGfl\"
		set lstIncoming to incoming lines of oShape
		if lstIncoming ≠ {} then
			set oLink to first item of lstIncoming
			set lstPath to my getpath(source of oLink, blnNodes, blnLinks)
			if blnLinks then set lstPath to lstPath & {oLink}
			if blnNodes then set lstPath to lstPath & {oShape}
		else
			if blnNodes then
				set lstPath to {oShape}
			else
				set lstPath to {}
			end if
		end if
		return lstPath
	end tell
end getpath"

tell application id "OGfl"
	repeat with oShape in shapes of canvas of front window
		set script of oShape to pScript
	end repeat
end tell

Post finally, I hadn't previously noticed that nodes can inherit a script from the template on which a document is based.

For example, any node in a hierarchy based on the attached template will foreground the color of its own ancestral links, in response to a Browse Tool click, and will gray out all other links in the diagram.

--