[mediaczar]

I can't find a means of bringing a selected graphic object to the front (as per the "Arrange > Bring to Front" Command)

Or indeed, sending it backwards.

Here's the issue. I'm using the following function to create links between nodes in a network, and the labels are (for whatever reason) drawing behind the connectors. I'd like to bring the label object forward, and can't.

Caveat: I'm new to AppleScript. It seems horribly undocumented.

on linkCircle(fromTag, toTag)
	tell application "OmniGraffle Professional 5"
		tell canvas of front window

			set fromCircle to the first solid whose tag = fromTag

			set toCircle to the first solid whose tag = toTag

			tell fromCircle
				set newConnection to connect to toCircle with ¬
				properties {line type:orthogonal}
			end tell
			
			set newLabel to make new shape at end of graphics ¬
			with properties {draws shadow:false, autosizing:full, ¬
			text:{text:"hello world", alignment:center}, ¬
			draws stroke:false}

			set labelConnection of newLabel to newConnection
		end tell
	end tell
end linkCircle

Originally Posted by mediaczar

I can't find a means of bringing a selected graphic object to the front (as per the "Arrange > Bring to Front" Command)

This is encoded in the order of the graphics collection of the canvas, so:

set newLabel to make new shape at beginning of graphics ¬
				with properties ¬
				{draws shadow:false, autosizing:full, text:{text:"hello world", alignment:center}, draws stroke:false}

Or, more generally:

on run
	tell application id "OGfl"
		tell front window
			set refGraphics to a reference to graphics of its canvas
			set lstSeln to selection
			repeat with oSeln in lstSeln
				my BringToFront(oSeln, refGraphics)
			end repeat
		end tell
	end tell
end run

on BringToFront(oGraphic, refGraphics)
	move oGraphic to beginning of refGraphics
end BringToFront

on SendToBack(oGraphic, refGraphics)
	move oGraphic to end of refGraphics
end SendToBack

[mediaczar]

Rob - many thanks. That's not only answered my question, but given me some insight into the whole approach. Was stumbling around in the dark before...

Thank you :)