(* This assumes that some rows are selected in OmniOutliner *)

on run
	
	-- SAVE A FRESH OO3 DOC USING JUST THE SELECTED LINES
	
	tell application "OmniOutliner Professional"
		set MyDoc to front document
		
		
		set FirstRowID to id of first selected row of MyDoc
		set FirstRow to a reference to row id FirstRowID of MyDoc
		set MyRowIDs to id of every selected row of MyDoc
		
		set oNewDoc to make new document
		set oNewFirst to make new row at end of oNewDoc
		
		repeat with MyRowIndex from 1 to count of MyRowIDs -- force forward loop
			set MyRowID to item MyRowIndex of MyRowIDs
			duplicate row id MyRowID of MyDoc to before oNewFirst
		end repeat
		delete last row of oNewDoc
		
		set FilePath to (POSIX path of (path to desktop) as string) & "foobar2.oo3" as POSIX file
		save oNewDoc in FilePath
		close oNewDoc
	end tell
	
	-- IMPORT THE SAVED DOCUMENT INTO OMNIGRAFFLE
	
	-- Assumes following settings
	---- View>Page_Breaks :OFF
	---- View>Zoom>Fit in Window
	--In Canavas Size inspector:
	---- Size is multiple of printer sheets OFF
	----Auto-adjust the canvas size ON
	----Print canvas on one printer sheet ON
	
	tell application "OmniGraffle Professional 5"
		activate
		set strPath to POSIX path of FilePath as string
		try
			set oDoc to import strPath
		end try
	end tell
end run