-- Make a new document containing all columns, and any selected rows, of the current document
-- Ver 0.3 RobTrew


property pNewDocTitle : "NEW DOC FROM SELECTED ROWS"

-- MAKE A NEW DOCUMENT CONTAINING:
-- 1.	ALL THE COLUMNS OF THE FRONT DOCUMENT
-- 2.	ANY ROWS SELECTED IN THE FRONT DOCUMENT

tell application "OmniOutliner Professional"
	set oDoc to front document
	
	set docNew to make new document with properties {name:pNewDocTitle}
	set width of topic column of docNew to width of topic column of oDoc
	
	-- COPY ADDITIONAL COLUMNS FROM ORIGINAL DOCUMENT
	repeat with iCol from 3 to count of columns of oDoc
		set oCol to column iCol of oDoc
		tell oCol
			set {varName, varType, varWidth} to {name, type, width}
		end tell
		tell docNew
			set oNewCol to make new column with properties {name:varName, type:varType, width:varWidth}
			if varType is popup then
				set refEnums to (a reference to enumerations of oCol)
				duplicate refEnums to end of enumerations of oNewCol
			end if
		end tell
	end repeat
	
	-- COPY ANY SELECTED ROWS INTO THE NEW DOCUMENT
	set refSeldRows to a reference to selected rows of oDoc
	set lstSeldRows to contents of refSeldRows
	if length of lstSeldRows > 0 then
		duplicate refSeldRows to the end of the children of docNew
		set expanded of rows of docNew to false
		activate
	end if
end tell