The Omni Group
These forums are now read-only. Please visit our new forums to participate in discussion. A new account will be required to post in the new forums. For more info on the switch, see this post. Thank you!

Go Back   The Omni Group Forums > OmniFocus > OmniFocus 1 for Mac
FAQ Members List Calendar Search Today's Posts Mark Forums Read

 
Default Time for Start Date Thread Tools Search this Thread Display Modes
This must have come up, but couldn't find it in search. I'd like to set the default time for Start Date (default is always 12:00am) the same way we can for Due Date. Most days I'm up past midnight - I don't like to see all the next day's tasks ("check calendar", "take vitamin", "pack lunch") popping up while I'm still thinking about the day before. Setting the start time to 6:00am solves this, but I must do it manually for each new task. Allowing me to set a default time in Preferences (so that all Start Dates are set to 6:00am) would save me a lot of work! - thanks
 
You can use Help --> Send Feedback to submit feature requests.
__________________
Cheers,

Curt
 
Quote:
Originally Posted by curt.clifton View Post
You can use Help --> Send Feedback to submit feature requests.
I agree that this would be a great feature, I prefer that most of my start times kick off from 8am - it would save me a reasonable amount of time if it were possible to have that as the default time.
 
I'm in the same boat. I have to manually configure every start date or else my phone will randomly chime at mid night on some nights.
 
Me too posts don't affect the development database. If you want your vote to count use Help → Send Feedback.
__________________
Cheers,

Curt
 
I think I've requested this feature for the Data Preference before, but wanted to be sure. Please mirror the option for a "Default Time for Due Dates" with a "Default time for Start Dates" option. In my case, the default of midnight is a bad time for reminders.

Or is there a "defaults write…" option that would allow me to change my Default time for Start Dates?

Cross-posting to this forum and Help>Send Feedback…

Eric Beavers twitter.com/ELBeavers
IM EricLBeavers blog www.beelers.org
 
In the meanwhile, if you want to check that there are no midnight starts, you can do a search and replace with applescript.

Something like this, for example:

Code:
-- Find and replace start dates
-- Edit properties below (integers in range 0 - 24 for hours, 0 - 60 for minutes)

property pFindHours : 0
property pFindMins : 0

property pReplaceHours : 6 -- Desired start (hours)
property pReplaceMins : 0 -- Desired start (mins)

on run
	tell application id "com.omnigroup.omnifocus"
		tell default document
			set lstTasks to (flattened tasks where start date is not missing value)
			set lngChanges to 0
			repeat with i from 1 to length of lstTasks
				set dteStart to start date of item i of lstTasks
				tell dteStart
					if (its hours = pFindHours and its minutes = pFindMins) then
						set {its hours, its minutes} to {pReplaceHours, pReplaceMins}
						set start date of item i of lstTasks to dteStart
						set lngChanges to lngChanges + 1
					end if
				end tell
			end repeat
		end tell
	end tell
	
	display dialog (lngChanges as string) & " start dates changed from  " & PadNum(pFindHours, 2) & ":" & PadNum(pFindMins, 2) & ¬
		" to " & PadNum(pReplaceHours, 2) & ":" & PadNum(pReplaceMins, 2) with title "Find & Replace Start Time"
end run

on PadNum(lngNum, lngDigits)
	set strNum to lngNum as string
	set lngGap to (lngDigits - (length of strNum))
	repeat while lngGap > 0
		set strNum to "0" & strNum
		set lngGap to lngGap - 1
	end repeat
	strNum
end PadNum
 
This is a fine example of the two-minute rule in GTD processing. I read the thread, clipped the thread to my OmniFocus inbox and put it in my Applescripts project, thinking it would be an easy project to write a script that let you adjust the start time of a bunch of actions. Rob looked at the request, thought to himself "I can type a script to adjust the start time of a bunch of actions in less than two minutes" and did it immediately :-)
 
Thanks RobTrew, works great.
 
Thank you for this script.
 
 


Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
start date default time suddenly different flyingdesigner OmniFocus 1 for Mac 0 2013-02-16 10:18 AM
Set default time for start dates? raxtor OmniFocus 1 for Mac 2 2012-11-05 06:28 AM
Making Start Date, Due Date, Estimate Default jessicatmt OmniFocus 1 for Mac 1 2012-08-06 01:23 PM
Default start time Olf OmniFocus 1 for Mac 1 2012-05-22 07:39 AM
Can Default Start Time be Changed pgrayu2 OmniFocus 1 for Mac 5 2012-04-18 08:26 AM


All times are GMT -8. The time now is 05:20 AM.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2018, vBulletin Solutions, Inc.