[rogbar]

If I want to restart my Mac, I hit Restart, and OS X closes down every app except OO. I get a message asking if I want to save changes. If I'm not there to physically hit Yes, then Restart stops.

Is there any way I can set a preference that OO will save upon Restart without my having to hit Yes?

Originally Posted by rogbar

Is there any way I can set a preference that OO will save upon Restart without my having to hit Yes?

Not as far as I can see, but an alternative might be to initiate the shut-down from a script (which could be launched by the operating system at a given time).

The script could, inter alia, look for OmniOutliner, and, if it is running, loop through any open windows and close them, with a save if needed.

A script, which you could add to the Finder script menu, and perhaps assign a keystroke to, might contain code roughly along these lines:

-- Closes OmniOutliner before Restarting OS X
-- Modified OmniOutliner documents are saved before they are closed.
-- OO documents with names like Untitled, or Untitled 2
-- are saved with filenames built from the current system date

property pAppToClose : "OOut"
property pUnSavedName : "Untitled"

on run
	if AppIsRunning(pAppToClose) then
		tell application id "com.omnigroup.OmniOutlinerPro3"
			set lstDoc to documents
			repeat with oDoc in lstDoc
				tell oDoc
					if modified then
						if name of oDoc contains pUnSavedName then
							set name of oDoc to ((current date) as string) & ".oo3"
						end if
						save
					end if
					close
				end tell
			end repeat
			quit
		end tell
	end if
	
	tell application id "com.apple.finder"
		restart
	end tell
end run

on AppIsRunning(strAppCode)
	tell application id "com.apple.systemevents"
		(creator type of processes) contains strAppCode
	end tell
end AppIsRunning