[jofftan]

One of my main use of OO is for control sheets and dashboard that I build for different Phase of project.

Since this operation are depend on activity I would LOVE to have conditional formatting based on check box or number.

I'm sure it can be helpful for many of us in many different projects.

Thank you

In the meanwhile, you can, of course, update formatting conditionally with an applescript.

These colors are illustrative (certainly not recommended :-) but the code may give some idea of how to start ...

property pstrColumnName : "Priority"

property plstCheckedColor : {65530, 49344, 49344}

property plstHiColor : {0, 0, 65530}
property plstMedColor : {0, 0, 0}
property plstLoColor : {0, 65530, 0}
property pstrGutter : "item-gutter-color(com.omnigroup.OmniOutliner)"
property pstrFontColor : "font-fill"

tell application "OmniOutliner Professional"
	tell front document
		repeat with oRow in rows
			
			-- set gutter color by state
			set oStyle to style of oRow
			if state of oRow is checked then
				set varGutter to plstCheckedColor
			else
				set varGutter to missing value
			end if
			
			set value of attribute pstrGutter of oStyle to varGutter
			
			-- set text color according to value of a numeric column named "Priority"
			set oCell to cell pstrColumnName of oRow
			set lngValue to value of oCell
			if lngValue is missing value then
				set varTextShade to plstMedColor
				
			else if lngValue ≥ 5 then
				set varTextShade to plstHiColor
			else if lngValue ≤ 2 then
				set varTextShade to plstLoColor
			else
				set varTextShade to plstMedColor
			end if
			
			set value of attribute pstrFontColor of oStyle to varTextShade
		end repeat
	end tell
end tell

[zgeary]

+1. Conditional formatting of a row based on a value in that row (say a checkbox column or a number column) would be VERY useful.